**SAS code for the heritability (H2 and *h2*) analysis**

ods trace off;

**proc** **printto** log=logtemp;

**proc** **printto** print=screentemp;

/\* The above commands prevent the output from being written to the screen and filling up the buffer. Turn these commands off when testing the code below, then turn it back on when it's good to go. \*/

**%macro** ***RILboot***; /\* "RILboot" is the name of the SAS Macro \*/

%do j=**1** %to **200**;

/\* Do to the number of bootstrap replicates \*/

%do i=**1** %to **325**;

/\* do to the actual number of lines (i.e., # of RI(AI)Ls) in the data set \*/

data psudo1; retain x; set work.RILS2; /\* RILS2 is the name of the file that contains the data, in the "work" directory \*/

if \_n\_=**1** then x=round(**324**\*ranuni(**0**)+**1**);

/\* set 1st number in parentheses to one less than the number of lines\*/

if line=x;

/\* The variable "line" should be labeled in increments of 1, from 1 to n, where n is the number of lines \*/

pseudoline=&i;

output psudo1;

proc append base=SS data=psudo1; run;

%end;

PROC MIXED DATA=SS;

CLASS block pseudoline rep;

MODEL lnCI= /ddfm=kr2;

RANDOM block;

RANDOM pseudoline;

ODS OUTPUT covparms=broadpseudocovs;

run;

/\* In the above, "lnCI" is the name of the dependent variable. The output dataset "broadpseudocovs" contains the variance components. The broad sense heritability H^2 = VL/(VL+VE) where VL is the among-pseudoline component of variance and VE is the residual component of variance \*/

PROC MIXED DATA=SS;

CLASS block pseudoline rep;

MODEL lnCI=x1-x169 /residual outp=bootresid ddfm=kr2;

run;

/\* In the above, the output dataset "bootresid" contains the original data and the residuals of the multiple regression y=x1+x2+...x169, where x(i) represents the genotype (0 or 1) at locus i. \*/

PROC MIXED DATA=bootresid;

CLASS block pseudoline rep;

MODEL resid= /ddfm=kr2;

RANDOM block;

RANDOM pseudoline;

ODS OUTPUT covparms=narrowpseudocovs;

run;

/\* In the above, "resid" is the residual of the regression in the preceding analysis. The output dataset "narrowpseudocovs" contains the variance components. The broad-sense heritability of the residuals, H^2\* is calculated as before. The narrow-sense heritability, h^2=H^2-H^2\*, as describe in the text \*/

PROC APPEND BASE=boot.bootbroad\_RILs2 DATA=broadpseudocovs;

PROC APPEND BASE=boot.bootnarrow\_RILs2 DATA=narrowpseudocovs;

/\* The above appends the data from the current bootstrap replicate to the datafiles "bootbroad" and "bootnarrow" in the "boot" directory. \*/

proc datasets gennum=all;

delete SS psudo1 broadpseudocovs bootresid narrowpseudocovs;

run;

/\* The above deletes all the file in the "work" directory. \*/

%end;

**%mend** RILboot;